

// UI SETUP

/*--------------------------------------*/
/*			EDDL UI Setup    			*/
/*--------------------------------------*/

MENU device_root_menu				// Configure
{
	STYLE MENU;
	LABEL "Test Sets";
	ITEMS 
	{
		DRIVE_SETUP_menu,
		PID_SETUP_window,
		MOTORIZED_POT_window,
		SKIP_REF_window,
		NETWORK_SETUP_window,
		ACCESS_TO_ALL_menu
    }
}

MENU diagnostic_root_menu			// Device Diagnostics
{
	STYLE MENU;
	LABEL "Diagnostics";
    ITEMS
	{
		OVERALL_STATUS_window,
		DRIVE_TEMPS_window,
		ALARM_DISPLAY_window,
		FAULT_LOG_window,
		RUN_TIME_HISTORY_window,
		IO_STATUS_window
	}
}

MENU process_variables_root_menu	// Process Variables
{
	STYLE MENU;
	LABEL "Process Variables";
	ITEMS
	{
		VARIABLES_window
	}
}


//***********************************
// ------------  MENUS  -------------
//***********************************

//***********************************
// Configure MENUS
//***********************************

MENU DRIVE_SETUP_menu
{
	STYLE MENU;
	LABEL "Drive Setup";
	ITEMS 
	{
		MOTOR_MAP_SETUP_window,
		REFERENCE_SELECTION_window,
		REFERENCE_CLAMPS_window,
		RAMPS_RATES_window,
		DIGITAL_IO_SETUP_window,
		ANALOG_IO_SETUP_window
	}
}

MENU ACCESS_TO_ALL_menu
{
	STYLE MENU;
	LABEL "Drive Setup";
	ITEMS 
	{
		MENU_1_window,
		MENU_2_window
	}
}



//***********************************
// Device Diagnostics MENUS
//***********************************

// NONE



//***********************************
// Process Variables MENUS
//***********************************

// NONE




//***********************************
// ---------  WINDOWS  --------------
//***********************************


//***********************************
// Configure WINDOWS
//***********************************


MENU MOTOR_MAP_SETUP_window
{
	STYLE WINDOW;
	LABEL "Motor Map";
	ITEMS 
	{	
		VOLTAGE_MODES_page,
		MOTOR_MAP_page,
		CATCH_A_SPINNING_MOTOR_page,
		PWM_SWITCHING_FREQUENCY_page
	}
}

MENU REFERENCE_SELECTION_window
{
	STYLE WINDOW;
	LABEL "Reference Selection";
	ITEMS 
	{		
		REFERENCE_SELECTION_page
	}
}

MENU REFERENCE_CLAMPS_window
{
	STYLE WINDOW;
	LABEL "Reference Clamps";
	ITEMS 
	{	
		REFERENCE_CLAMPS_page
	}
}

MENU RAMPS_RATES_window
{
	STYLE WINDOW;
	LABEL "Ramp Rates";
	ITEMS 
	{		
		RAMPS_RATES_page
	}
}

MENU DIGITAL_IO_SETUP_window
{
	STYLE WINDOW;
	LABEL "Digital I/O Setup";
	ITEMS 
	{		
		DIG_IO_SOURCE_AND_DEST_page,
		DIG_IO_INVERT_PARAM_page,
		DIG_IO_OUT_SELECT_PARAM_page
	}
}

MENU ANALOG_IO_SETUP_window
{
	STYLE WINDOW;
	LABEL "Analog I/O Setup";
	ITEMS 
	{	
		ANALOG_IN_1_page,
		ANALOG_IN_2_page,
		ANALOG_OUT_1_page
	}
}

MENU PID_SETUP_window
{
	STYLE WINDOW;
	LABEL "PID Setup";
	ITEMS 
	{		
		PID_SETUP_page,
		PID_STATUS_page
	}
}

MENU MOTORIZED_POT_window
{
	STYLE WINDOW;
	LABEL "Motorized Pot Setup";
	ITEMS 
	{		
		MOTORIZED_POT_SETUP_page
	}
}

MENU SKIP_REF_window
{
	STYLE WINDOW;
	LABEL "Skip References Setup";
	ITEMS 
	{		
		SKIP_REF_SETUP_page
	}
}

MENU NETWORK_SETUP_window
{
	STYLE WINDOW;
	LABEL "Network Setup";
	ITEMS 
	{	
		NETWORK_SETUP_page
	}
}

MENU MENU_1_window
{
	STYLE WINDOW;
	LABEL "Menu 1";
	ITEMS 
	{
		MENU_1_GRID_page
	}
}

MENU MENU_2_window
{
	STYLE WINDOW;
	LABEL "Menu 2";
	ITEMS 
	{	
		MENU_2_GRID_page
	}
}


//***********************************
// Device Diagnostics WINDOWS
//***********************************

MENU OVERALL_STATUS_window
{
	STYLE WINDOW;
	LABEL "Device Status";
	ITEMS
	{
		OVERALL_STATUS_page
	}
}

MENU DRIVE_TEMPS_window
{
	STYLE WINDOW;
	LABEL "Drive Temperatures";
	ITEMS
	{
		DRIVE_TEMPS_page,
		DRIVE_TEMPS_VERT_BAR_page,
		DRIVE_TEMPS_GAUGE_page
	}
}

MENU ALARM_DISPLAY_window
{
	STYLE WINDOW;
	LABEL "Alarm Display";
	ITEMS
	{
		ALARM_DISPLAY_page
	}
}

MENU FAULT_LOG_window
{
	STYLE WINDOW;
	LABEL "Fault Log";
	ITEMS
	{
		FAULT_LOG_GRID_page
	}
}

MENU RUN_TIME_HISTORY_window
{
	STYLE WINDOW;
	LABEL "Run Time History";
	ITEMS
	{
		RUN_TIME_HISTORY_page
	}
}

MENU IO_STATUS_window
{
	STYLE WINDOW;
	LABEL "I/O Status";
	ITEMS
	{
		DIGITAL_IO_STATUS_page,
		ANALOG_IO_STATUS_page
	}
}



//***********************************
// Process Variables WINDOWS
//***********************************

MENU VARIABLES_window
{
	STYLE WINDOW;
	LABEL "Variables";
	ITEMS
	{
		DRIVE_VARIABLES_page,
		PROCESS_VARIABLES_page
	}
}




//***********************************
// --------  PAGES & GROUPS  --------
//***********************************


//***********************************
// Configure PAGES & GROUPS
//***********************************

MENU VOLTAGE_MODES_page
{
	STYLE PAGE;
	LABEL "Voltage Modes";
	ITEMS 
	{
		VOLTAGE_MODE_GROUP_1	
	}
}

MENU VOLTAGE_MODE_GROUP_1
{
	STYLE GROUP;
	LABEL "Voltage Mode Setup";
	HELP "Parameters used to congfigure the desired voltage mode";
	ITEMS
	{
		M5_P14,
		M5_P15
	}
}

MENU MOTOR_MAP_page
{
	STYLE PAGE;
	LABEL "Motor Map";
	ITEMS 
	{
		MOTOR_SETUP_PARS_GROUP_1,
		MOTOR_SETUP_PARS_GROUP_2
	}
}

MENU MOTOR_SETUP_PARS_GROUP_1
{
	STYLE GROUP;
	LABEL "Motor Parameters";
	HELP "These parameters are used to configure the motor";
	ITEMS
	{
		M5_P6,
		M5_P7,
		M5_P8,
		M5_P9,
		M5_P10,
		M5_P11
	}
}

MENU MOTOR_SETUP_PARS_GROUP_2
{
	STYLE GROUP;
	LABEL "Auto Tune";
	HELP "The Autotune feature can be used to measure certain motor parameters";
	ITEMS
	{
		M5_P12
	}
}

MENU CATCH_A_SPINNING_MOTOR_page
{
	STYLE PAGE;
	LABEL "Catch a Spinning Motor";
	ITEMS 
	{
		CATCH_SPIN_MOT_GROUP_1
	}
}

MENU CATCH_SPIN_MOT_GROUP_1
{
	STYLE GROUP;
	LABEL "Catch a Spinning Motor Setup";
	ITEMS
	{
		M6_P9
	}
}

MENU PWM_SWITCHING_FREQUENCY_page
{
	STYLE PAGE;
	LABEL "PWM Switching Frequency";
	ITEMS 
	{
		PWM_SW_FREQ_GROUP_1
	}
}

MENU PWM_SW_FREQ_GROUP_1
{
	STYLE GROUP;
	LABEL "Drive Switching Freq Parameters";
	ITEMS
	{
		M5_P18,
		M5_P35
	}
}

MENU REFERENCE_SELECTION_page
{
	STYLE PAGE;
	LABEL "Reference Selection";
	ITEMS 
	{
		REFERENCE_SELECTION_GROUP_1
	}
}

MENU REFERENCE_SELECTION_GROUP_1
{
	STYLE GROUP;
	LABEL "Reference Selection";
	ITEMS
	{
		M1_P14
	}
}

MENU REFERENCE_CLAMPS_page
{
	STYLE PAGE;
	LABEL "Reference Clamps";
	ITEMS 
	{
		REFERENCE_CLAMPS_GROUP_1		
	}
}

MENU REFERENCE_CLAMPS_GROUP_1
{
	STYLE GROUP;
	LABEL "Reference Clamp Setup";
	ITEMS
	{
		M1_P6,
		M1_P7
	}
}

MENU RAMPS_RATES_page
{
	STYLE PAGE;
	LABEL "Ramp Rates";
	ITEMS 
	{
		RAMP_RATE_GROUP_1,
		COLUMNBREAK,
		RAMPS_RATES
	}
}

MENU RAMP_RATE_GROUP_1
{
	STYLE GROUP;
	LABEL "Ramp Setup";
	ITEMS
	{
		M2_P11, 
		M2_P21,
		M2_P39,
		M2_P6,
		M6_P1
	}
}

MENU DIG_IO_SOURCE_AND_DEST_page
{
	STYLE PAGE;
	LABEL "Digital I/O Source and Destination";
	ITEMS 
	{
		DIG_IO_SRCDEST_GROUP_1,
		DIG_IO_SRCDEST_GROUP_2
	}
}

MENU DIG_IO_SRCDEST_GROUP_1
{
	STYLE GROUP;
	LABEL "I/O Sources and Destinations";
	ITEMS
	{
		M8_P21,
		M8_P22,
		M8_P23,
		M8_P24,
		M8_P25,
		M8_P27
	}
}

MENU DIG_IO_SRCDEST_GROUP_2
{
	STYLE GROUP;
	LABEL "Auto Select Outputs";
	ITEMS
	{
		M8_P41
	}
}

MENU DIG_IO_INVERT_PARAM_page
{
	STYLE PAGE;
	LABEL "Digital I/O Invert Parameters";
	ITEMS 
	{
		DIG_IO_INVERT_GROUP_1
	}
}

MENU DIG_IO_INVERT_GROUP_1
{
	STYLE GROUP;
	LABEL "Analog Input 1 Parameters";
	ITEMS
	{
		M8_P11,
		M8_P12,
		M8_P13,
		M8_P14,
		M8_P15,
		M8_P17
	}
}

MENU DIG_IO_OUT_SELECT_PARAM_page
{
	STYLE PAGE;
	LABEL "Digital I/O Output Select Parameters";
	ITEMS 
	{
		DIG_IO_OUT_SELECT_GROUP_1
	}
}

MENU DIG_IO_OUT_SELECT_GROUP_1
{
	STYLE GROUP;
	LABEL "Digital I/O Setup Parameters";
	ITEMS
	{
		M8_P31,
		M8_P35
	}
}

MENU ANALOG_IN_1_page
{
	STYLE PAGE;
	LABEL "Analog Input 1";
	ITEMS 
	{
		ANALOG_IN_1_GROUP_1
	}
}

MENU ANALOG_IN_1_GROUP_1
{
	STYLE GROUP;
	LABEL "Analog Input 1 Parameters";
	ITEMS
	{
		M7_P8,
		M7_P9,
		M7_P10,
		M7_P30
	}
}

MENU ANALOG_IN_2_page
{
	STYLE PAGE;
	LABEL "Analog Input 2";
	ITEMS 
	{
		ANALOG_IN_2_GROUP_1
	}
}

MENU ANALOG_IN_2_GROUP_1
{
	STYLE GROUP;
	LABEL "Analog Input 2 Parameters";
	ITEMS
	{
		M7_P11,
		M7_P12,
		M7_P13,
		M7_P14,
		M7_P31
	}
}

MENU ANALOG_OUT_1_page
{
	STYLE PAGE;
	LABEL "Analog Output 1";
	ITEMS 
	{
		ANALOG_OUT_1_GROUP_1	
	}
}

MENU ANALOG_OUT_1_GROUP_1
{
	STYLE GROUP;
	LABEL "Analog Output 1 Parameters";
	ITEMS
	{
		M7_P19,
		M7_P20
	}
}

MENU PID_SETUP_page
{
	STYLE PAGE;
	LABEL "PID Reference Source & Destination Setup";
	ITEMS 
	{
		M14_P8,
		PID_Vars_Group_1,
		COLUMNBREAK,
		" ",
		PID_Vars_Group_2,
		COLUMNBREAK,
		" ",
		PID_Vars_Group_3,
		PID_Vars_Group_4
	}
}

MENU PID_Vars_Group_1
{
	STYLE GROUP;
	LABEL "Source/Destination";
	HELP "The Souce and Destination setup parameters";
	ITEMS
	{
		M14_P2,
		M14_P3,
		M14_P4,
		" ",
		M14_P16
	}
}

MENU PID_Vars_Group_2
{
	STYLE GROUP;
	LABEL "Setup Tools";
	HELP "Tools for modifying behavior of the PID Loop";
	ITEMS
	{
		M14_P5,
		M14_P6,
		M14_P7
	}
}

MENU PID_Vars_Group_3
{
	STYLE GROUP;
	LABEL "PID Tuning";
	HELP "Parameters used to tune the the PID Loop";
	ITEMS
	{
		M14_P10,
		M14_P11,
		M14_P12,
		M14_P13,
		M14_P14,
		M14_P15
	}
}

MENU PID_Vars_Group_4
{
	STYLE GROUP;
	LABEL "PID Tools";
	HELP "PID Loop Functions";
	ITEMS
	{
		M14_P17,
		M14_P18
	}
}

MENU PID_STATUS_page
{
	STYLE PAGE;
	LABEL "PID Status";
	ITEMS 
	{
		
		PID_Status_Group_1
	}
}

MENU PID_Status_Group_1
{
	STYLE GROUP;
	LABEL "PID Loop Status";
	HELP "Status parameters give realtime information about performance of the PID Loop";
	ITEMS
	{
		M14_P1,
		M14_P19,
		M14_P20,
		M14_P21,
		M14_P22
	}
}


MENU MOTORIZED_POT_SETUP_page
{
	STYLE PAGE;
	LABEL "Motorized Potentiometer Setup";
	ITEMS 
	{
		MOTORIZED_POT_Setup_Group_1,
		COLUMNBREAK,
		MOTORIZED_POT_Status_Group_1		
	}
}

MENU MOTORIZED_POT_Setup_Group_1
{
	STYLE GROUP;
	LABEL "Motorized Pot Setup";
	HELP "Configure the Motorized Pot functionality";
	ITEMS
	{
		M9_P21,
		M9_P22,
		M9_P23,
		M9_P24,
		MOTORIZED_POT_STATUS
	}
}

MENU MOTORIZED_POT_Status_Group_1
{
	STYLE GROUP;
	LABEL "Motorized Pot Status";
	HELP "Status parameters give realtime information about performance of the Motorized Pot function";
	ITEMS
	{
		M9_P3
	}
}

MENU SKIP_REF_SETUP_page
{
	STYLE PAGE;
	LABEL "Skip References Setup";
	ITEMS 
	{
		SKIP_REF_Setup_Group_1,
		SKIP_REF_Setup_Group_2,
		SKIP_REF_Setup_Group_3,
		COLUMNBREAK,
		SKIP_REF_Status_Group_1,
		COLUMNBREAK,
		SKIP_REF (INLINE),
		SKIP_REF_Info_Group_1
	}
}

MENU SKIP_REF_Setup_Group_1
{
	STYLE GROUP;
	LABEL "Skip Reference 1";
	HELP "Configure the Skip Reference 1 parameters";
	ITEMS
	{
		M1_P29,
		M1_P30
	}
}

MENU SKIP_REF_Setup_Group_2
{
	STYLE GROUP;
	LABEL "Skip Reference 2";
	HELP "Configure the Skip Reference 2 parameters";
	ITEMS
	{
		M1_P31,
		M1_P32
	}
}

MENU SKIP_REF_Setup_Group_3
{
	STYLE GROUP;
	LABEL "Skip Reference 3";
	HELP "Configure the Skip Reference 3 parameters";
	ITEMS
	{
		M1_P33,
		M1_P34
	}
}

MENU SKIP_REF_Status_Group_1
{
	STYLE GROUP;
	LABEL "Skip Reference Status";
	HELP "Parameter indicates whether the actual command is within one of the defined skip reference bands";
	ITEMS
	{
		M1_P35		
	}
}

MENU SKIP_REF_Info_Group_1
{
	STYLE GROUP;
	LABEL "Setup Information";
	ITEMS
	{
		"Three skip references are available to prevent continuous operation "
		"at a speed that would cause mechanical resonance. The skip reference band "
		"parameters define the frequency range on either side of the programmed "
		"skip reference, over which references are rejected. Therefore, the actual reject "
		"band is twice the value programmed in the parameters, with the skip "
		"reference defining the center of the band. When the selected "
		"reference is within one of the bands, the lower limit of the band is always used."
		"                                                                               "
		"To disable a given Skip Reference, simply set the Skip Reference parameter to a "
		"value of zero."
	}
}

MENU NETWORK_SETUP_page
{
	STYLE PAGE;
	LABEL "Network Setup";
	ITEMS 
	{
		NETWORK_Setup_Group_1
	}
}

MENU NETWORK_Setup_Group_1
{
	STYLE GROUP;
	LABEL "Network Setup";
	HELP "Configure the communications network parameters";
	ITEMS
	{
		M11_P23,
		M11_P24,
		M11_P25
	}
}

MENU MENU_1_GRID_page
{
	STYLE PAGE;
	LABEL "Menu 1 Parameters";
	ITEMS 
	{
		" ",
		BIG_SK,
		COLUMNBREAK,
		MENU_1_GRID
	}
}

MENU MENU_2_GRID_page
{
	STYLE PAGE;
	LABEL "Menu 2 Parameters";
	ITEMS 
	{
		" ",
		BIG_SK,
		COLUMNBREAK,
		MENU_2_GRID
	}
}


//***********************************
// Device Diagnostics PAGES & GROUPS
//***********************************

MENU OVERALL_STATUS_page
{
	STYLE PAGE;
	LABEL "Drive Status";
	ITEMS
	{
		M10_P40 (READ_ONLY),
		COLUMNBREAK,
		M2_P1,
		M4_P4,
		M5_P5,
		COLUMNBREAK,
		M5_P1,
		M4_P2,
		M1_P21	
	}
}

MENU DRIVE_TEMPS_page
{
	STYLE PAGE;
	LABEL "Drive Temperatures";
	ITEMS
	{
		M7_P6,
		M7_P35,
		M7_P34,
		COLUMNBREAK,
		M7_P4,
		M7_P5,
		M7_P36,
		DRIVE_TEMPS_Group1	
	}
}

MENU DRIVE_TEMPS_Group1
{
	// Drive Temps Info
	
	STYLE GROUP;
	LABEL "Information";
	HELP "This box contains information about Drive Temperatures.";
	ITEMS
	{
		"Drive Temps Information Here"
	}
}

MENU DRIVE_TEMPS_VERT_BAR_page
{
	STYLE PAGE;
	LABEL "Drive Temperature Vertical Bars";
	ITEMS
	{
		DRIVE_TEMPS_Group1,
		ROWBREAK,
		TemperatureVertBarChart_1,
		COLUMNBREAK,
		TemperatureVertBarChart_2,
		COLUMNBREAK,
		TemperatureVertBarChart_3	
	}
}

SOURCE Temp1
{
	LINE_TYPE DATA;
	Y_AXIS TEMP_AXIS_1; 
	MEMBERS
	{
		TEMP1, M7_P6, M7_P6_LABEL ;
	}
}

SOURCE Temp2
{
	LINE_TYPE DATA;
	Y_AXIS PERCENT_AXIS; 
	MEMBERS
	{
		TEMP2, M7_P35, M7_P35_LABEL ;
	}
}

SOURCE Temp3
{
	LINE_TYPE DATA;
	Y_AXIS TEMP_AXIS_1; 
	MEMBERS
	{
		TEMP3, M7_P34, M7_P34_LABEL ;
	}
}

SOURCE Temp4
{
	LINE_TYPE DATA;
	Y_AXIS TEMP_AXIS_1; 
	MEMBERS
	{
		TEMP4, M7_P4, M7_P4_LABEL ;
	}
}

SOURCE Temp5
{
	LINE_TYPE DATA;
	Y_AXIS TEMP_AXIS_1; 
	MEMBERS
	{
		TEMP5, M7_P5, M7_P5_LABEL ;
	}
}

SOURCE Temp6
{
	LINE_TYPE DATA;
	Y_AXIS TEMP_AXIS_2; 
	MEMBERS
	{
		TEMP6, M7_P36, M7_P36_LABEL ;
	}
}

CHART TemperatureVertBarChart_1
{
	LABEL "Drive Tempeatures";
	TYPE VERTICAL_BAR;
	CYCLE_TIME 1000*60*1;
	WIDTH X_SMALL; 
	MEMBERS
	{
		ONE,	Temp1, M7_P6_LABEL;
		THREE,	Temp3;
		FOUR,	Temp4;
		FIVE,	Temp5;
	}
}

CHART TemperatureVertBarChart_2
{
	LABEL "Drive Thrermal Accumulator";
	TYPE VERTICAL_BAR;
	CYCLE_TIME 1000*60*1;
	WIDTH X_SMALL; 
	MEMBERS
	{
		TWO,	Temp2;
	}
}

CHART TemperatureVertBarChart_3
{
	LABEL "IGBT Junction Tempeature";
	TYPE VERTICAL_BAR;
	CYCLE_TIME 1000*60*1;
	WIDTH X_SMALL; 
	MEMBERS
	{
		SIX,	Temp6;
	}
}

AXIS TEMP_AXIS_1 
{
    LABEL "Temp (Deg C)";
	SCALING LINEAR; 
    MIN_VALUE 0;
	MAX_VALUE 127;        
}

AXIS TEMP_AXIS_2
{
    LABEL "Temp (Deg C)";
	SCALING LINEAR; 
    MIN_VALUE 0;
	MAX_VALUE 200;        
}

AXIS PERCENT_AXIS
{
	LABEL "%";
	HELP "0 to 100% Axis";
	MIN_VALUE  0;
	MAX_VALUE  100;
}

MENU DRIVE_TEMPS_GAUGE_page
{
	STYLE PAGE;
	LABEL "Drive Temperature Gauges";
	ITEMS
	{
		
		TEMP_METER_1,
		TEMP_METER_4,
		COLUMNBREAK,
		TEMP_METER_3,
		TEMP_METER_5,
		COLUMNBREAK,
		TEMP_METER_2,
		TEMP_METER_6				
	}
}

CHART TEMP_METER_1
{
	//LABEL M7_P6_LABEL;
	LABEL "Control Board Temp (°C)";
	HELP "Control Board Temp (°C)";
	TYPE GAUGE;
	HEIGHT MEDIUM;
	WIDTH X_SMALL; 
	MEMBERS
	{
		TEMP_METER_ONE,	Temp1;
	}
}

CHART TEMP_METER_2
{
	//LABEL M7_P35_LABEL;
	LABEL "Drive Thermal Accumulator (%)";
	HELP M7_P35_LABEL;
		TYPE GAUGE;
	HEIGHT MEDIUM;
	WIDTH X_SMALL; 
	MEMBERS
	{
		TEMP_METER_TWO,	Temp2;
	}
}

CHART TEMP_METER_3
{
	//LABEL M7_P34_LABEL;
	LABEL "IGBT Junction Temp (°C)";
	HELP "IGBT Junction Temp (°C)";
	TYPE GAUGE;
	HEIGHT MEDIUM;
	WIDTH X_SMALL; 
	MEMBERS
	{
		TEMP_METER_TWO,	Temp3;
	}
}

CHART TEMP_METER_4
{
	//LABEL M7_P4_LABEL;
	LABEL "Stack Temp 1 (°C)";
	HELP "Stack Temp 1 (°C)";
	TYPE GAUGE;
	HEIGHT MEDIUM;
	WIDTH X_SMALL; 
	MEMBERS
	{
		TEMP_METER_ONE,	Temp4;
	}
}

CHART TEMP_METER_5
{
	//LABEL M7_P5_LABEL;
	LABEL "Stack Temp 2 (°C)";
	HELP "Stack Temp 2 (°C)";
	TYPE GAUGE;
	HEIGHT MEDIUM;
	WIDTH X_SMALL; 
	MEMBERS
	{
		TEMP_METER_TWO,	Temp5;
	}
}

CHART TEMP_METER_6
{
	//LABEL M7_P36_LABEL;
	LABEL "Stack Temp 3 (°C)";
	HELP "Stack Temp 3 (°C)";
	TYPE GAUGE;
	HEIGHT MEDIUM;
	WIDTH X_SMALL; 
	MEMBERS
	{
		TEMP_METER_TWO,	Temp6;
	}
}


MENU ALARM_DISPLAY_page
{
	STYLE PAGE;
	LABEL "Alarm Display";
	ITEMS
	{
		M10_P12 (READ_ONLY),
		M10_P15 (READ_ONLY),
		M10_P17 (READ_ONLY),
		COLUMNBREAK,
		M10_P18 (READ_ONLY),
		M10_P19 (READ_ONLY),
		M10_P32 (READ_ONLY),
		COLUMNBREAK,
		ALARM_DISPLAY_Group1		
	}
}

MENU ALARM_DISPLAY_Group1
{
	// Alarm Display Info
	
	STYLE GROUP;
	//LABEL "Information";
	HELP "This box contains information Alarms and how to handle them.";
	ITEMS
	{
		"Refer to the Commander SK User Guide for Trip, Warning, and Alarm information and solutions."
	}
}

MENU FAULT_LOG_page
{
	STYLE PAGE;
	LABEL "Fault Log";
	ITEMS
	{
		FAULT_LOG_Group_1,
		FAULT_LOG_Group_2		
	}
}

MENU FAULT_LOG_Group_1
{
	// Trips 0 - 9 Trip Code
	
	STYLE GROUP;
	LABEL "Fault Log (Trip Code - Associated Trip Time)";
	HELP "This list contains the ten most recent drive trips (Trip 0 = Most recent).";
	ITEMS
	{
		M10_P20,
		M10_P21,
		M10_P22,
		M10_P23,
		M10_P24,
		M10_P25,
		M10_P26,
		M10_P27,
		M10_P28,
		M10_P29
	}
}

MENU FAULT_LOG_Group_2
{
	// Fault Info
	
	STYLE GROUP;
	//LABEL "Information";
	HELP "This list contains the error codes for the option modules populated in the three drive slots";
	ITEMS
	{
		"Refer to the Commander SK User Guide for Trip, Warning, and Alarm information and solutions."
	}
}

MENU FAULT_LOG_GRID_page
{
	STYLE PAGE;
	LABEL "Fault Log";
	ITEMS
	{
		"The below grid indicates the past ten drive trips stored in memory (Trip 1 = Most recent).",
		DRIVE_FAULT_LOG_DISPLAY
	}
}

GRID DRIVE_FAULT_LOG_DISPLAY
{

	LABEL "Drive Fault Log" ;
	HELP "This list contains the ten most recent drive trips (Trip 0 = Most recent)" ;
	//VALIDITY boolean-specifier;
	HEIGHT  SMALL;
	WIDTH  SMALL;
	ORIENTATION  VERTICAL ;
	HANDLING  READ ;
	VECTORS
	{
		{ "Trip Number",
								0,
								1,
								2,
								3,
								4,
								5,
								6,
								7,
								8,
								9},
		/*{ "String",			"str1",
								"str2",
								"str3",
								"str4",
								"str5",
								"str6",
								"str7",
								"str8",
								"str9",
								"str10"},*/
		{ "Trip Code",
								M10_P20,
								M10_P21,
								M10_P22,
								M10_P23,
								M10_P24,
								M10_P25,
								M10_P26,
								M10_P27,
								M10_P28,
								M10_P29}
		
	}
}

GRID MENU_1_GRID
{
	LABEL "Menu 1 - Frequency / Speed Reference" ;
	HELP "This list contains the parameter values for each parameter in Menu 1" ;
	HEIGHT  X_LARGE;
	WIDTH  SMALL;
	ORIENTATION  VERTICAL;
	VECTORS
	{
		{ "Parameter #",		"1.01", "1.02", "1.03", "1.04", "1.05", "1.06", "1.07", "1.09", "1.10",
								"1.11", "1.12", "1.13", "1.14", "1.15", "1.17", "1.18", "1.19", "1.20",
								"1.21", "1.22", "1.23", "1.24", "1.25", "1.26", "1.27", "1.28", "1.29", "1.30",
								"1.31", "1.32", "1.33", "1.34", "1.35", "1.36", "1.37", "1.38",
								"1.41", "1.42", "1.43", "1.44", "1.45", "1.46", "1.47", "1.49", "1.50",
								"1.51"},
							  
		{ "Parameter Name", 	M1_P1_LABEL, M1_P2_LABEL,	M1_P3_LABEL, M1_P4_LABEL, M1_P5_LABEL, M1_P6_LABEL, M1_P7_LABEL, M1_P9_LABEL, M1_P10_LABEL,
								M1_P11_LABEL, M1_P12_LABEL,	M1_P13_LABEL, M1_P14_LABEL, M1_P15_LABEL, M1_P17_LABEL, M1_P18_LABEL, M1_P19_LABEL, M1_P20_LABEL,
								M1_P21_LABEL, M1_P22_LABEL,	M1_P23_LABEL, M1_P24_LABEL, M1_P25_LABEL, M1_P26_LABEL, M1_P27_LABEL, M1_P28_LABEL, M1_P29_LABEL, M1_P30_LABEL,
								M1_P31_LABEL, M1_P32_LABEL,	M1_P33_LABEL, M1_P34_LABEL, M1_P35_LABEL, M1_P36_LABEL, M1_P37_LABEL, M1_P38_LABEL,
								M1_P41_LABEL, M1_P42_LABEL,	M1_P43_LABEL, M1_P44_LABEL, M1_P45_LABEL, M1_P46_LABEL, M1_P47_LABEL, M1_P49_LABEL, M1_P50_LABEL,
								M1_P51_LABEL },
								
		{ "Value",			    M1_P1, M1_P2, M1_P3, M1_P4, M1_P5, M1_P6, M1_P7, M1_P9, M1_P10,
								M1_P11, M1_P12,	M1_P13, M1_P14, M1_P15, M1_P17, M1_P18, M1_P19, M1_P20,
								M1_P21, M1_P22,	M1_P23, M1_P24, M1_P25, M1_P26, M1_P27, M1_P28, M1_P29, M1_P30,
								M1_P31, M1_P32,	M1_P33, M1_P34, M1_P35, M1_P36, M1_P37, M1_P38,
								M1_P41, M1_P42,	M1_P43, M1_P44, M1_P45, M1_P46, M1_P47, M1_P49, M1_P50,
								M1_P51 },
		
		{ "Units",				M1_P1_UNIT, M1_P2_UNIT,	M1_P3_UNIT, M1_P4_UNIT, M1_P5_UNIT, M1_P6_UNIT, M1_P7_UNIT, M1_P9_UNIT, M1_P10_UNIT,
								M1_P11_UNIT, M1_P12_UNIT, M1_P13_UNIT, M1_P14_UNIT, M1_P15_UNIT, M1_P17_UNIT, M1_P18_UNIT, M1_P19_UNIT, M1_P20_UNIT,
								M1_P21_UNIT, M1_P22_UNIT, M1_P23_UNIT, M1_P24_UNIT, M1_P25_UNIT, M1_P26_UNIT, M1_P27_UNIT, M1_P28_UNIT, M1_P29_UNIT, M1_P30_UNIT,
								M1_P31_UNIT, M1_P32_UNIT, M1_P33_UNIT, M1_P34_UNIT, M1_P35_UNIT, M1_P36_UNIT, M1_P37_UNIT, M1_P38_UNIT,
								M1_P41_UNIT, M1_P42_UNIT, M1_P43_UNIT, M1_P44_UNIT, M1_P45_UNIT, M1_P46_UNIT, M1_P47_UNIT, M1_P49_UNIT, M1_P50_UNIT,
								M1_P51_UNIT }
	}
 
}

GRID MENU_2_GRID
{
	LABEL "Menu 2 - Ramps" ;
	HELP "This list contains the parameter values for each parameter in Menu 2" ;
	HEIGHT  X_LARGE;
	WIDTH  SMALL;
	ORIENTATION  VERTICAL;
	VECTORS
	{
		{ "Parameter #",		"2.01", "2.03", "2.04", "2.06", "2.07", "2.08", "2.10",
								"2.11", "2.12", "2.13", "2.14", "2.15", "2.16", "2.17", "2.18", "2.19", "2.20",
								"2.21", "2.22", "2.23", "2.24", "2.25", "2.26", "2.27", "2.28", "2.29", "2.30",
								"2.31", "2.32", "2.33", "2.34", "2.35", "2.36", "2.37", "2.39" },
							  
		{ "Parameter Name", 	M2_P1_LABEL, M2_P3_LABEL, M2_P4_LABEL, M2_P6_LABEL, M2_P7_LABEL, M2_P8_LABEL, M2_P10_LABEL,
								M2_P11_LABEL, M2_P12_LABEL,	M2_P13_LABEL, M2_P14_LABEL, M2_P15_LABEL, M2_P16_LABEL, M2_P17_LABEL, M2_P18_LABEL, M2_P19_LABEL, M2_P20_LABEL,
								M2_P21_LABEL, M2_P22_LABEL,	M2_P23_LABEL, M2_P24_LABEL, M2_P25_LABEL, M2_P26_LABEL, M2_P27_LABEL, M2_P28_LABEL, M2_P29_LABEL, M2_P30_LABEL,
								M2_P31_LABEL, M2_P32_LABEL, M2_P33_LABEL, M2_P34_LABEL, M2_P35_LABEL, M2_P36_LABEL, M2_P37_LABEL, M2_P39_LABEL },
								
		{ "Value",			    M2_P1, M2_P3, M2_P4, M2_P6, M2_P7, M2_P8, M2_P10,
								M2_P11, M2_P12,	M2_P13, M2_P14, M2_P15, M2_P16, M2_P17, M2_P18, M2_P19, M2_P20,
								M2_P21, M2_P22,	M2_P23, M2_P24, M2_P25, M2_P26, M2_P27, M2_P28, M2_P29, M2_P30,
								M2_P31, M2_P32, M2_P33, M2_P34, M2_P35, M2_P36, M2_P37, M2_P39 },
		
		//**  The below Units for M2_P11 through M2_P30 have been substitued with M21_P4_UNIT unit since I can't use a variable employing a SELECT statement here **
		// Default unit for these parameters is s/100Hz
		// TODO: Fix this problem

		{ "Units",				M2_P1_UNIT, M2_P3_UNIT, M2_P4_UNIT, M2_P6_UNIT, M2_P7_UNIT, M2_P8_UNIT, M2_P10_UNIT,
								M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT,
								M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT, M21_P4_UNIT,
								M2_P31_UNIT, M2_P32_UNIT, M2_P33_UNIT, M2_P34_UNIT, M2_P35_UNIT, M2_P36_UNIT, M2_P37_UNIT, M2_P39_UNIT }
	}
 
}

MENU RUN_TIME_HISTORY_page
{
	STYLE PAGE;
	LABEL "Run Time History";
	ITEMS
	{
		"The parameters below indicate how long the drive has been in the Run state since the drive was manufactured.",
		RUN_TIME_HISTORY_Group_1
	}
}

MENU RUN_TIME_HISTORY_Group_1
{
	// Run Time
	
	STYLE GROUP;
	LABEL "Drive History";
	HELP "These parameters show how long the Commander SK has been powered up and enabled";
	ITEMS
	{
		M6_P22,
		M6_P23
	}
}

MENU DIGITAL_IO_STATUS_page
{
	STYLE PAGE;
	LABEL "Digital I/O Status";
	ITEMS
	{
		DIGITAL_IO_STATUS_Group_1
	}
}

MENU DIGITAL_IO_STATUS_Group_1
{
	// Digital IO Status
	
	STYLE GROUP;
	LABEL "Digital I/O Status";
	HELP "This group contains the status of each of the Digital I/O on the SK";
	ITEMS
	{
		M8_P1,
		M8_P2,
		M8_P3,
		M8_P4,
		M8_P5,
		M8_P7
	}
}

MENU ANALOG_IO_STATUS_page
{
	STYLE PAGE;
	LABEL "Analog I/O Status";
	ITEMS
	{
		ANALOG_IO_STATUS_Group_1
	}
}

MENU ANALOG_IO_STATUS_Group_1
{
	// Analog IO Status
	
	STYLE GROUP;
	LABEL "Analog I/O Status";
	HELP "This group contains the status of each of the Analog I/O on the SK";
	ITEMS
	{
		M7_P1,
		M7_P2,
		M7_P28
	}
}


//***********************************
// Process Variables PAGES & GROUPS
//***********************************


MENU DRIVE_VARIABLES_page
{
	STYLE PAGE;
	LABEL "Drive Variables";
	ITEMS
	{
		CURRENT_CONTROL_GROUP,
		MOTOR_CONTROL_GROUP,
		DRIVE_RUNTIME_GROUP,
		ENERGY_GROUP,
		COLUMNBREAK,
		DRIVE_STATUS_GROUP,
		OVERLOAD_GROUP
	}
}

MENU CURRENT_CONTROL_GROUP
{
	STYLE GROUP;
	LABEL "Current Control";
	ITEMS
	{
		M4_P17
	}
}

MENU MOTOR_CONTROL_GROUP
{
	STYLE GROUP;
	LABEL "Motor Control";
	ITEMS
	{
		M5_P5
	}
}

MENU DRIVE_RUNTIME_GROUP
{
	STYLE GROUP;
	LABEL "Drive Runtime";
	ITEMS
	{
		M6_P22,
		M6_P23
	}
}

MENU ENERGY_GROUP
{
	STYLE GROUP;
	LABEL "Energy";
	ITEMS
	{
		M6_P24,
		M6_P25
	}
}

MENU DRIVE_STATUS_GROUP
{
	STYLE GROUP;
	LABEL "Drive Status";
	ITEMS
	{
		M10_P1,
		M10_P2
	}
}

MENU OVERLOAD_GROUP
{
	STYLE GROUP;
	LABEL "Overload";
	ITEMS
	{
		M4_P19,
		M10_P39
	}
}

MENU PROCESS_VARIABLES_page
{
	STYLE PAGE;
	LABEL "Process Variables";
	ITEMS
	{
		FREQUENCY_REFERENCE_GROUP,
		COLUMNBREAK,
		CURRENT_LOAD_GROUP,
		COLUMNBREAK,
		OUTPUT_GROUP
	}
}

MENU FREQUENCY_REFERENCE_GROUP
{
	STYLE GROUP;
	LABEL "Frequency Reference";
	ITEMS
	{
		M1_P1,
		M1_P2,
		M1_P3,
		M2_P1
	}
}

MENU CURRENT_LOAD_GROUP
{
	STYLE GROUP;
	LABEL "Current / Load";
	ITEMS
	{
		M4_P1,
		M4_P2,
		M4_P20,
		M4_P26,
		M4_P4
	}
}

MENU OUTPUT_GROUP
{
	STYLE GROUP;
	LABEL "Output";
	ITEMS
	{
		M5_P1,
		M5_P2,
		M5_P3,
		M5_P4
	}
}

